Difference between revisions of "Vlc"
| Line 17: | Line 17: | ||
priority="0"> | priority="0"> | ||
| − | <check type="uninstall" condition="exists" path="VideoLAN VLC media player 0.9. | + | <check type="uninstall" condition="exists" path="VideoLAN VLC media player 0.9.4" /> |
<install cmd='"%SOFTWARE%\vlc\vlc-0.9.2-win32.exe" /S' /> | <install cmd='"%SOFTWARE%\vlc\vlc-0.9.2-win32.exe" /S' /> | ||
<install cmd='%CMD% /c del "%ALLUSERSPROFILE%\Desktop\VLC media player.lnk"' /> | <install cmd='%CMD% /c del "%ALLUSERSPROFILE%\Desktop\VLC media player.lnk"' /> | ||
Revision as of 21:06, 9 October 2008
VLC (Video LAN Client) is a multimedia player.
Simple method
The second install command removes the desktop shortcut (the path may have to be changed to a localized name).
<?xml version="1.0" encoding="UTF-8"?>
<packages>
<package
id="vlc"
name="Video LAN Client"
revision="1"
reboot="false"
priority="0">
<check type="uninstall" condition="exists" path="VideoLAN VLC media player 0.9.4" />
<install cmd='"%SOFTWARE%\vlc\vlc-0.9.2-win32.exe" /S' />
<install cmd='%CMD% /c del "%ALLUSERSPROFILE%\Desktop\VLC media player.lnk"' />
<remove cmd='"%PROGRAMFILES%\VideoLAN\VLC\uninstall.exe" /S' />
</package>
</packages>
Upgrade is also possible, but there are issues. See the advanced method for how to achieve this.
Advanced method by SkyBeam
VLC is a bit tricky because upgrading (installation if an installed version is already installed) is not fully unattended. It interactively asks the user if the existing version should be uninstalled first. As already mentioned above a solution would be to remove the previous version first before installing the VLC update. However also this fails since uninstall.exe forks a new process while the parent exits immediately. So if this happens too quickly then the install program still asks for confirmation.
So I did a small workaround for that:
<?xml version="1.0" encoding="utf-8" ?>
<packages>
<package id='VLC' name='VLC media player' revision='9200' priority='50' reboot='false' >
<!-- VLC media player -->
<check type='uninstall' condition='exists' path='VLC media player 0.9.2' />
<install cmd='"%SOFTWARE%\VLC\unattended.cmd"' />
<remove cmd='"%SOFTWARE%\VLC\unattended-uninstall.cmd"' />
<upgrade cmd='"%SOFTWARE%\VLC\unattended.cmd"' />
</package>
</packages>
I am using these scripts (unattended.cmd, unattended-uninstall.cmd) because they need to perform some more actions. Here are the contents:
unattended.cmd
@echo off
set BINARY=vlc-0.9.4-win32.exe
echo Installing VLC media plyer
set INSTALLER_LOC=%~dp0
set EXIT_CODE=0
set PROG_FILES=%ProgramFiles%
if not "%ProgramFiles(x86)%" == "" set PROG_FILES=%ProgramFiles(x86)%
echo - Removing previous version "%INSTALLER_LOC%unattended-uninstall.cmd"
call "%INSTALLER_LOC%unattended-uninstall.cmd"
echo - Installing player
start /wait "VLC" "%INSTALLER_LOC%%BINARY%" /S /NCRC /D="%PROG_FILES%"
set EXIT_CODE=%ERRORLEVEL%
call "%INSTALLER_LOC%cleanup.cmd"
exit /B %EXIT_CODE%
As you can see it calls unattended-uninstall.cmd prior to installation (any time!). The evaluation of PROG_FILES assures that it installs the 32-bit VLC player always to the correct program files directory also on 64-bit systems.
unattended-uninstall.cmd
@echo off
echo Removing VLC media plyer
if not "%ProgramFiles(x86)%" == "" set PROG_FILES=%ProgramFiles(x86)%
set INSTALLER_LOC=%~dp0
set VLANDIR=%PROG_FILES%\VideoLAN
set UNINSTALLER=%VLANDIR%\VLC\uninstall.exe
set OPTIONS=/S
if not exist "%UNINSTALLER%" goto good_end
start /wait "VLC uninstall" "%UNINSTALLER%" %OPTIONS%
REM Unfortunately the uninstaller seems to fork a child process and the parent
REM process exits immediately. So give it some time to uninstall
for /L %%C IN (1,1,30) DO (
if not exist "%UNINSTALLER%" goto good_end
ping -n 1 127.0.0.1
)
:bad_end
exit 1
:good_end
if exist "%VLANDIR%" rmdir "%VLANDIR%"
exit /B 0
As this script is called by unattended.cmd also when VLC is probably not installed it first checks if there is an uninstallation to be done. If not it just skips the uninstall, but still checks to see if the uninstaller totally cleaned up after itself.
As I wrote above the uninstaller forks a child process and exits immediately. So there is a need to wait for the uninstaller to complete. I am simply checking if the uninstaller still exists. If yes I wait for another second.
In order to prevent an endless-loop the uninstallation will stop after a maximum of 30 seconds.
Finally here's my cleanup.cmd. script:
@echo off
echo Removing unnecessary shortcuts
del /F /Q "%ALLUSERSPROFILE%\Desktop\VLC media player**"
del /F /Q "%PUBLIC%\Desktop\VLC media player**"
exit /B 0
This has been tested on Windows Vista x64.