Difference between revisions of "Vlc"
| Line 132: | Line 132: | ||
As described in the [http://nsis.sourceforge.net/When_I_use_ExecWait_uninstaller.exe_it_doesn%27t_wait_for_the_uninstaller NSIS Wiki], there is a command line argument to prevent the uninstaller from backgrounding. It cannot delete itself in this case, though so you need to do that separately. Thus an alternative uninstall command sequence is: | As described in the [http://nsis.sourceforge.net/When_I_use_ExecWait_uninstaller.exe_it_doesn%27t_wait_for_the_uninstaller NSIS Wiki], there is a command line argument to prevent the uninstaller from backgrounding. It cannot delete itself in this case, though so you need to do that separately. Thus an alternative uninstall command sequence is: | ||
<source lang="xml"> | <source lang="xml"> | ||
| − | <uninstall cmd='"%ProgramFiles%\VideoLAN\VLC\uninstall.exe /S _?= | + | <uninstall cmd='"%ProgramFiles%\VideoLAN\VLC\uninstall.exe /S _?=%ProgramFiles%\VideoLAN\VLC'/> |
<uninstall cmd='%COMSPEC% /C rmdir /S /Q "%ProgramFiles%\VideoLAN"'/> | <uninstall cmd='%COMSPEC% /C rmdir /S /Q "%ProgramFiles%\VideoLAN"'/> | ||
</source> | </source> | ||
| + | Note that there must not be spaces around the path that follows _?= | ||
[[category:Silent Installers]] | [[category:Silent Installers]] | ||
[[category:Security Advisories]] | [[category:Security Advisories]] | ||
Revision as of 11:31, 5 November 2009
VLC (VideoLAN Client) is a multimedia player. It plays a very wide range of audio and video and DVD.
For security reasons you are encouraged to update to version 0.9.8a: http://www.videolan.org/security/sa0811.html.
Contents
Simple Method
This install method removes the desktop shortcut (the path may have to be changed to your localized name).
<?xml version="1.0" encoding="UTF-8"?>
<packages>
<package
id="vlc"
name="VideoLAN Client"
revision="2"
reboot="false"
priority="0">
<check type="uninstall" condition="exists" path="VLC media player 0.9.8a" />
<install cmd='"%SOFTWARE%\vlc\vlc-0.9.8a-win32.exe" /S' />
<!--<install cmd='%CMD% /c del "%ALLUSERSPROFILE%\Desktop\VLC media player.lnk"' />-->
<remove cmd='"%PROGRAMFILES%\VideoLAN\VLC\uninstall.exe" /S' />
</package>
</packages>
Upgrade is also possible, but there are issues. See the advanced method for how to achieve this.
Advanced method by SkyBeam
VLC is a bit tricky because upgrading (installation if an installed version is already installed) is not fully unattended. It interactively asks the user if the existing version should be uninstalled first. As already mentioned above a solution would be to remove the previous version first before installing the VLC update. However also this fails since uninstall.exe forks a new process while the parent exits immediately. So if this happens too quickly then the install program still asks for confirmation.
So I did a workaround for that:
<?xml version="1.0" encoding="utf-8" ?>
<packages>
<package id='VLC' name='VideoLAN Client' revision='1' priority='50' reboot='false' >
<!-- VLC media player -->
<check type='uninstall' condition='exists' path='VLC media player 0.9.6' />
<install cmd='"%SOFTWARE%\VLC\unattended.cmd"' />
<remove cmd='"%SOFTWARE%\VLC\unattended-uninstall.cmd"' />
<upgrade cmd='"%SOFTWARE%\VLC\unattended.cmd"' />
</package>
</packages>
This method requires the following scripts to perform some more actions:
unattended.cmd
@echo off
set BINARY=vlc-0.9.6-win32.exe
echo Installing VLC media plyer
set INSTALLER_LOC=%~dp0
set EXIT_CODE=0
set PROG_FILES=%ProgramFiles%
if not "%ProgramFiles(x86)%" == "" set PROG_FILES=%ProgramFiles(x86)%
echo - Removing previous version "%INSTALLER_LOC%unattended-uninstall.cmd"
call "%INSTALLER_LOC%unattended-uninstall.cmd"
echo - Installing player
start /wait "VLC" "%INSTALLER_LOC%%BINARY%" /S /NCRC /D="%PROG_FILES%"
set EXIT_CODE=%ERRORLEVEL%
call "%INSTALLER_LOC%cleanup.cmd"
exit /B %EXIT_CODE%
As you can see it calls unattended-uninstall.cmd prior to installation (any time!). The evaluation of PROG_FILES assures that it installs the 32-bit VLC always to the correct program files directory also on 64-bit systems.
unattended-uninstall.cmd
@echo off
echo Removing VLC media plyer
set PROG_FILES=%ProgramFiles%
if not "%ProgramFiles(x86)%" == "" set PROG_FILES=%ProgramFiles(x86)%
set INSTALLER_LOC=%~dp0
set VLANDIR=%PROG_FILES%\VideoLAN
set UNINSTALLER=%VLANDIR%\VLC\uninstall.exe
set OPTIONS=/S
if not exist "%UNINSTALLER%" goto good_end
start /wait "VLC uninstall" "%UNINSTALLER%" %OPTIONS%
REM Unfortunately the uninstaller seems to fork a child process and the parent
REM process exits immediately. So give it some time to uninstall
for /L %%C IN (1,1,30) DO (
if not exist "%UNINSTALLER%" goto good_end
ping -n 2 127.0.0.1 > NUL
)
:bad_end
exit /B 1
:good_end
if exist "%VLANDIR%" rmdir /s /q "%VLANDIR%"
exit /B 0
As this script is called by unattended.cmd also when VLC is probably not installed it first checks if there is an uninstallation to be done. If not it just skips the uninstall, but still checks to see if the uninstaller totally cleaned up after itself.
As described above the uninstaller forks a child process and exits immediately. So there is a need to wait for the uninstaller to complete. I am simply checking if the uninstaller still exists. If yes I wait for another second.
In order to prevent an endless-loop the uninstallation will stop after a maximum of 30 seconds.
cleanup.cmd
@echo off
echo Removing unnecessary shortcuts
del /F /Q "%ALLUSERSPROFILE%\Desktop\VLC media player**"
del /F /Q "%PUBLIC%\Desktop\VLC media player**"
exit /B 0
This has been tested on Windows Vista x64.
Alternative method without forking
As described in the NSIS Wiki, there is a command line argument to prevent the uninstaller from backgrounding. It cannot delete itself in this case, though so you need to do that separately. Thus an alternative uninstall command sequence is:
<uninstall cmd='"%ProgramFiles%\VideoLAN\VLC\uninstall.exe /S _?=%ProgramFiles%\VideoLAN\VLC'/>
<uninstall cmd='%COMSPEC% /C rmdir /S /Q "%ProgramFiles%\VideoLAN"'/>
Note that there must not be spaces around the path that follows _?=